1 GOTO10
2 *************************************
3 *             THE SWORD             *
4 *     VON A.SOMMER UND S.ADOMAT     *
5 * KLAUS-GROTH-STR.12   2210 ITZEHOE *
6 *         TEL.: 04821/3164          *
7 *************************************
10 POKE808,234
14 PRINT"[147] LOADING..."
15 SYS57812"A",8,1:POKE780,0:SYS65493
16 SYS57812"B",8,1:POKE780,0:SYS65493
20 POKE53280,6:POKE53281,6:PRINTCHR$(147)CHR$(8)CHR$(14):POKE650,0:POKE53269,0
21 SYS820
50 PRINT"[147][150]       [208]INK [193]RTS PROUDLY PRESENTS:"
60 PRINT"             >[144] [212]HE [211]WORD <[144]"
65 PRINT"            @ 1986 [193].[211]OMMER"
67 PRINT"               AND [211].[193]DOMAT"
70 FORT=1TO1000:NEXT
75 PRINT"               [212]HANKS TO"
80 PRINT"       [194]IRTHE,[195]LAUDIA,THE GIRLS..."
90 FORT=1TO1000:NEXT
95 PRINT"               (WAITING)"
100 AV=15:DIMVE$(AV)
101 AO=32:DIMNO$(AO),O$(AO),O(AO)
102 AR=41:DIMRA$(AR),DU(AR,6),KR$(AR)
103 AU=18:DIMAU$(AU)
104 AF=9:DIMFL(AF)
105 SP=1:F1=0:F2=15:F3=15:F0=6:ZU=0:PO=0
106 A2=28:DIMV2$(A2)
107 AZ=4:DIMZA$(AZ)
131 DATANIMM,LEGE,GEHE,BETRETE,VERLASSE,TOETE,RUDERE,LEG
132 DATAVERLIERE,LESE,LIES,HEIRATE,GEH,BESTEIGE,UNTERSUCHE
141 DATA"/","NORDEN",0
142 DATA"/","SUEDEN",0
143 DATA"/","WESTEN",0
144 DATA"/","OSTEN",0
145 DATA"/","OBEN",0
146 DATA"/","UNTEN",0
147 DATA"/","MIR",0
148 DATA"/","MICH",0
149 DATA"DEN HEILIGEN [205]ANN","MANN",2
150 DATA"EIN [194]OOT","BOOT",3
151 DATA"KEIN [194]OOT","BOOT",9
152 DATA"DIE LIEBLICHE [194]IRTHE","BIRTHE",10
153 DATA"DIE NIEDLICHE [195]LAUDIA","CLAUDIA",10
154 DATA"DIE HEISSBLUETIGE [195]HRISTIANE","CHRISTIANE",10
155 DATA"DIE RESERVIERTE [205]EIKE","MEIKE",10
156 DATA"DIE NETTE [211]ANDRA","SANDRA",10
157 DATA"VIELE GROSSE UND KLEINE [211]TEINE","STEINE",11
158 DATA"[194]AEUME","BAUEME",14
159 DATA"[194]AEUME","BAEUME",15
160 DATA"EINE KLEINE,ALTE [200]UETTE","HUETTE",16
161 DATA"EINEN [205]ORGENSTERN","MORGENSTERN",19
162 DATA"EINEN KOSTBAREN [211]CHILD","SCHILD",19
163 DATA"EIN VERGILBTES [194]LATT [208]APIER","BLATT",24
164 DATA"EINEN (DEN!) [218]WERG","ZWERG",32
165 DATA"DEN [196]RACHEN,DEN ICH TOETEN MUSS","DRACHEN",33
166 DATA"GAR NICHTS,NUR LAUTER UEBELRICHENDEN    [206]EBEL","NEBEL",35
167 DATA"KEINE [210]ETTUNG FUER MICH","RETTUNG",41
168 DATA"/","PAPIER",0
169 DATA"/","FRAU",0
170 DATA"/","ALLES",0
171 DATA"DAS [218]AUBERSCHWERT","ZAUBERSCHWERT",33
172 DATA"EINE [204]AMPE","LAMPE",-1
201 DATA"VOR DEM HEILIGEN [212]URM.","[214]ORM HEILIGEN [212]URM",2,0,0,0,0,0
202 DATA"IM HEILIGEN [212]URM.[203]ALT HIER...","[201]M [212]URM",9,1,5,6,10,3
203 DATA"IM [203]ELLER.[200]IER FLIESST EIN      [198]LUSS.","[203]ELLER",0,0,0,0,2,0
204 DATA"IM [194]OOT.","[201]M [194]OOT",0,0,0,0,0,0
205 DATA"IM [205]OOR.","[205]OOR",8,0,0,2,0,0
206 DATA"AM [205]EER.","[193]M [205]EER",0,0,2,0,0,0
207 DATA"IM [194]OOT.","[201]M [194]OOT",0,0,0,0,0,0
208 DATA"IM [205]OOR.","[205]OOR",0,0,0,0,0,0
209 DATA"AM [198]LUSS.","[193]M [198]LUSS",11,2,0,0,0,0
210 DATA"IM [200]AREM DES HEILIGEN [205]ANNES.","[201]M [200]AREM",0,0,0,0,0,2
211 DATA"IM [199]EBIRGE.","[199]EBIRGE",11,11,11,11,12,9
212 DATA"AUF DEM [199]IPFEL DER [199]ENUESSE.","[199]IPFEL",0,0,0,0,0,0
213 DATA"AUF EINER [211]ANDBANK.([205]IST!)","[211]ANDBANK",0,0,0,0,0,0
214 DATA"IM [215]ALD.","[215]ALD",15,0,14,14,0,0
215 DATA"IM [215]ALD.","[215]ALD",16,14,15,14,0,0
216 DATA"IM [215]ALD VOR EINER [200]UETTE.","[214]OR EINER [200]UETTE",15,15,15,14,0,0
217 DATA"IN DER KLEINEN [200]UETTE.","[200]UETTE",0,0,0,0,0,0
218 DATA"AM [211]EE [203]ALTOR.","[203]ALTOR",21,0,41,19,0,0
219 DATA"AUF EINER [197]BENE.","[197]BENE",0,0,18,0,0,0
220 DATA"AUF EINER WEITEN [197]BENE.","[197]BENE",0,0,0,21,0,0
221 DATA"AN EINEM [198]LUSS.","[198]LUSS",22,18,20,0,0,0
222 DATA"AM [198]LUSS.","[198]LUSS",23,21,20,0,0,0
223 DATA"AM [198]LUSS.","[198]LUSS",24,22,20,0,0,0
224 DATA"AM [210]AND DES [199]EBIRGES.","[199]EBIRGSRAND",26,23,23,23,0,0
225 DATA"IM [199]EBIRGE.","[199]EBIRGE",28,0,39,26,0,0
226 DATA"IM [199]EBIRGE.","[199]EBIRGE",29,24,25,27,0,0
227 DATA"IN EINEM [212]AL.","[212]AL",30,0,26,0,0,0
228 DATA"IM [199]EBIRGE.","[199]EBIRGE",0,25,39,29,0,0
229 DATA"IN EINEM [212]AL.","[212]AL",31,26,28,30,0,0
230 DATA"IM [199]EBIRGE.","[199]EBIRGE",0,27,30,0,0,0
231 DATA"IN EINEM [212]AL.","[212]AL",0,29,0,0,0,32
232 DATA"IN EINER DUESTEREN [200]OEHLE.","[200]OEHLE",0,0,0,0,31,0
233 DATA"TIEF IN DER [200]OEHLE DES [204]OEWEN...AEHH [196]RACHEN,NATUERLICH!"
234 DATA"[200]OEHLE",0,0,0,0,34,0
235 DATA"IN DER [200]OEHLE DES [196]RACHEN.","[200]OEHLE",0,0,0,35,0,33
236 DATA"AM [198]USSE DES [214]ETUS.","[214]ETUS",0,40,34,36,0,0
237 DATA"AUF EINER [197]BENE.[198]ERN IM [215]ESTEN  RAUCHT DER [214]ETUS.","[197]BENE"
238 DATA0,0,35,37,0,0
239 DATA"AUF EINER [197]BENE.","[197]BENE",39,38,36,38,0,0
240 DATA"AUF EINER [197]BENE.","[197]BENE",39,37,37,39,0,0
241 DATA"AUF EINER [197]BENE.","[197]BENE",38,25,38,28,0,0
242 DATA"AUF EINER [197]BENE.","[197]BENE",35,40,40,40,0,0
243 DATA"UNTER [215]ASSER...","[213]NTER [215]ASSER",0,0,0,0,0,0
300 DATADER,DIE,DAS,DEN, ,UEBER,UNTER,AUF,IN,MIT,DEM,DURCH,UND,NACH
301 DATABITTE,DOCH,HEILIGEN,ZUR
501 DATA0,0,0,0,0,0,0,0,0
601 DATAINVENTORY,HILFE,ENDE,SIEH,LOOK,DANKE,SAVE,LOAD,STORE,RESTORE,FARBE
602 DATANORDEN,SUEDEN,WESTEN,OSTEN,OBEN,UNTEN,SCORE,SPIELSTAND,SAGE,SCHLAFE
603 DATASPEICHERE,LADE,ANLEITUNG,SPIELANLEITUNG,NORMAL,NEU,WARTE
650 REM ZAUBERSPRUECHE
651 DATAEMMIWHCS,KCEURUZ,"EHCARD ETEOT","THCIL"
700 DATA133,95,134,96,76,191,163
800 FORT=1TOAV:READVE$(T):NEXT
801 FORT=1TOAO:READNO$(T),O$(T),O(T)
802 NEXT
803 FORT=1TOAR:READRA$(T),KR$(T)
804 FORX=1TO6:READDU(T,X):NEXTX,T
805 FORT=1TOAU:READAU$(T):NEXT
806 FORT=1TOAF:READFL(T):NEXT
807 FORT=1TOA2:READV2$(T):NEXT
808 FORT=1TOAZ:READZA$(T):ZA$(T)=CHR$(34)+ZA$(T)+CHR$(34):NEXT
810 FORT=704TO710:READA:POKET,A:NEXT
820 POKE88,0:POKE89,192:POKE90,0:POKE91,192:POKE780,0:POKE781,160:SYS704
825 POKE88,0:POKE89,0:POKE90,0:POKE91,0:POKE780,0:POKE781,224:SYS704
830 POKE1,53
900 PRINT"[145]       [206]ORMALER [218]EICHENSATZ?  [164][157]";
920 GETA$:IFA$<>"N"ANDA$<>"J"THEN920
930 PRINTA$
931 FORT=1TO500:NEXT
940 IFA$="J"THENGOSUB56000:PRINTCHR$(14):F0=0:F1=5:F2=3:F3=5
945 POKE53280,F0:POKE53281,F0
1000 POKE59639,0
1005 PRINT"[147]"
1006 DATA"[206]ORDEN","[211]UEDEN","[215]ESTEN","[207]STEN","[207]BEN","[213]NTEN"
1010 FORT=1TO6:READRI$(T):NEXT
1020 PRINTCHR$(147)
1080 GOSUB53000:PRINT:POKE646,F1:IFSP=2THENFL(2)=-1
1090 PRINT"[201]CH BIN ";RA$(SP)
1100 PRINT"[201] CAN SEE:"
1110 FL(1)=-1:FORT=1TOAO
1120 IFO(T)=SPTHENPRINTNO$(T)".":FL(1)=0
1130 NEXT
1140 IFFL(1)THENPRINT"NICHTS."
1150 PRINT"[200]IER GEHT'S NACH:"
1160 G=0:FORT=1TO6
1170 IFDU(SP,T)<>0THENPRINTRI$(T)",";:G=G+1
1180 NEXT
1190 IFG<1THENPRINT"NIRGENDWOHIN ";
1200 PRINT"[157]."
1230 IFFL(2)ANDO(9)=2THENO(9)=0:GOSUB57000:GOTO1080
1300 IFSP=8THENPRINT"[200]ILFE,ICH VERSINKE IM [205]OOR...":GOTO54000
1310 IFSP=13THENPRINT"[212]JA,DAS [193]BENTEUER IST LEIDER ZUENDE."
1320 IFSP=13THENPRINT"[201]CH VERHUNGERE LANGSAM,UND DENKE"
1330 IFSP=13THENPRINT"AN DIE [218]EIT,DIE ICH MIT [194]IRTHE HAETTE"
1340 IFSP=13THENPRINT"VERBRINGEN KOENNEN.":PRINT:GOTO54000
1370 :
1500 ZU=ZU+1:IFFL(5)ANDNOTFL(8)THENPO=PO+1:FL(8)=-1
1501 IFSP<>41THENFL(7)=0
1502 IFSP=41THENFL(7)=FL(7)+1
1503 IFFL(7)>2THENPRINT"[201]CH ERTRINKE...[194]LUBB...":PRINT:GOTO54000
1505 GOSUB50000:POKE646,F2
1510 IFLEN(X$)>2THEN1600
1520 IFX$="N"ANDDU(SP,1)<>0THENSP=DU(SP,1):PRINT"[194]ITTE.":GOTO1080
1521 IFX$="S"ANDDU(SP,2)<>0THENSP=DU(SP,2):PRINT"[206]A [199]UT.":GOTO1080
1523 IFX$="W"ANDDU(SP,3)<>0THENSP=DU(SP,3):PRINT"[199]OOOOD.":GOTO1080
1524 IFX$="O"ANDDU(SP,4)<>0THENSP=DU(SP,4):PRINT"[206]A [203]LAR.":GOTO1080
1525 IFX$="OB"ANDDU(SP,5)<>0THENSP=DU(SP,5):PRINT"[193]BER [194]ITTE.":GOTO1080
1526 IFX$="U"ANDDU(SP,6)<>0THENSP=DU(SP,6):PRINT"[194]ITTESCHOEN.":GOTO1080
1527 IFX$="I"THEN31000
1599 PRINT"[215]RONG [201]NPUT!":GOTO1500
1600 ER=0:GOSUB51000
1610 IFER=1THEN1500
1615 ER=0:GOSUB52000
1616 IFER=1THEN1500
1620 IFV2<>0THEN30000
1630 IFO1=28THENO1=23
1640 IFO1=18ANDSP=15THENO1=19
1650 IFO1=10ANDSP=9THENO1=11
1700 ONVGOTO2500,2000,3000,3500,4000,4500,5000,2000,6500,7000,7000,7500
1710 ONV-12GOTO3000,6000,8000
1800 GOTO1500
2000 IFO2<>0THENPRINT"[201]MMER DER [210]EIHE NACH!":GOTO1500
2005 IFO1=30THEN2100
2010 IFNOTO(O1)THENPRINT"[200]ABE ICH NICHT DABEI!":GOTO1500
2020 O(O1)=SP:PRINT"[199]ELEGT!":GOTO1500
2100 GL=0:FORT=1TOAO
2110 IFO(T)=-1THENO(T)=SP:PRINTO$(T)":GELEGT":GL=1
2120 NEXT
2130 IFGL=1THEN1500
2140 PRINT"[200]ATTE LEIDER NOTHING DABEI!":GOTO1500
2500 IFO1=30THEN2800
2501 IFO2=29THENO2=0:GOTO7500
2502 IFO1=8THENPRINT"[196]U HASST DICH DOCH SCHON!":GOTO1500
2503 IFO1=7THENPRINT"[204]ERN ERSTMAL [196]EUTSCH!":GOTO1500
2504 IFO(O1)=-1THENPRINT"[200]AB ICH DOCH SCHON!":GOTO1500
2505 IFO(O1)<>SPTHENPRINT"[211]EHE ICH HIER NICHT!":GOTO1500
2506 IFO1=11THENPRINT"[196]A OBEN STEHT [203][197][201][206] [194]OOT!":GOTO1500
2507 IFO1<12THENPRINT"[196]AS GEHT NUN WIRKLICH NICHT!":GOTO1500
2508 IFO1<17THENPRINT"[196]U DENKST AUCH NUR AN DAS EINE!":GOTO1500
2509 IFO1=17THENPRINT"[211]O VIELE...KANN MICH NICHT ENTSCHEIDEN!":GOTO1500
2510 IFO1=18ORO1=19THENPRINT"[194]IN DOCH KEIN [210]IESE,NUR EIN KLEINER [195]64!";:GOTO1500
2511 IFO1=20THENPRINT"[196]AS SOLLTEST DU DIR NOCHMAL UEBERLEGEN!":GOTO1500
2512 IFO1>23ANDO1<31THENPRINT"[206]EIN,DAS UEBERSTEIGT MEINE [203]OMPETENZEN!":GOTO1500
2530 IFO1=31ANDNOTFL(6)THENPRINT"[196]ER [196]RACHE [214]ERFEUERT DICH IM [214]ULKAN!":GOTO54000
2600 O(O1)=-1:PRINT"[193]LLRIGHT,GETAKET!"
2610 IFO(31)THENFL(5)=-1
2630 GOTO1500
2800 GN=0:FORT=1TOAO
2810 IFO(T)=SPTHENGOSUB2850
2820 NEXT
2830 IFGN=0THENPRINT"[206]ICHTS DA!"
2840 GOTO1500
2850 IFT<>21ANDT<>22ANDT<>23ANDT<>32THEN2900
2860 PRINTO$(T)":GENOMMEN":O(T)=-1:GN=1:RETURN
2900 IFT=31ANDFL(6)=-1THENFL(5)=-1:GOTO2860
2905 IFT=31ANDNOTFL(6)THENO1=31:GOTO2530
2910 RETURN
3000 IFO2<>0THENPRINT"[197]INS AUF EINMAL!":GOTO1500
3010 IFO1=1THENX$="N":GOTO1520
3020 IFO1=2THENX$="S":GOTO1521
3030 IFO1=3THENX$="W":GOTO1523
3040 IFO1=4THENX$="O":GOTO1524
3050 IFO1=5THENX$="OB":GOTO1525
3060 IFO1=6THENX$="U":GOTO1526
3070 PRINT"[206]IT MOEGLICH...":GOTO1500
3500 IFO2<>0THENPRINT"[206]O,MAN!":GOTO1500
3510 IFO1=10THEN6000
3520 IFO(O1)<>SPTHENPRINT"[211]EH ICK NICH!":GOTO1500
3530 IFO1<>20THENPRINT"[211]OWAS KANN ICH NICHT BETRETEN!":GOTO1500
3540 PRINT"[194]IN DRIN!":SP=17:PO=PO+1:GOTO1080
4000 IFO2<>0THENPRINT"[211][207] [206][201][195][200][212]!":GOTO1500
4010 IFO1<>10ANDO1<>20THENPRINT"[196]AS GEHT NICHT!":GOTO1500
4020 IFO1=20ANDSP=17THENPRINT"[211]IE LAESST MICH NICHT RAUS!":GOTO1500
4030 IFSP<>4ANDSP<>7ANDO1<>10THENPRINT"[214]ERSTEH' DICH NICHT!":GOTO1500
4040 IFSP=4THENPRINT"[200]ILFE,ICH ERTRINKE...":GOTO54000
4050 SP=14:PRINT"[199]UTE [215]AHL!":GOTO1080
4100 PRINT"[204]EIDER UNMOEGLICH!":GOTO1500
4500 IFO1=8THENPRINT"[211]ELBSTMORD IST UNTER [211]TRAFE VERBOTEN!":GOTO1500
4501 IFO1=7THENPRINT"[204]ERN ERSTMAL RICHTIG [196]EUTSCH!":GOTO1500
4505 IFO(O1)<>SPORO2<>0ANDO2<>21THENPRINT"[214]ERSTEHE ICH NICHT.":GOTO1500
4510 IFO1=9ORO1=24ORO1=25ORO1>11ANDO1<17THEN4600
4530 PRINT"[197]IN [196][201]NG KANN MAN [206][201][195][200][212] TOETEN!":GOTO1500
4600 IFO2=21THENPRINT"[196]AMI GEHTS NICHT!":GOTO1500
4609 PRINT"[215]OMIT DENN?"
4610 PRINT"[213]ND UEBERHAUPT:[205]ORDEN IST GAR NICHT "
4620 PRINT"FEIN!":GOTO1500
5000 IFO1>4ORO2<>0THENPRINT"[211]O EIN [194]LOEDSINN!":GOTO1500
5010 IFSP<>7ANDSP<>4THENPRINT"[207]HNE [194]OOT UND OHNE [215]ASSER???":GOTO1500
5020 IFSP=7ANDO1=2THENSP=4:PRINT"[193]LLRIGHT!":GOTO1080
5030 IFSP=4ANDO1=1THENSP=7:PRINT"[194]ITTESCHOEN!":GOTO1080
5040 IFO1=3THENSP=13:PRINT"[211]ELBST SCHULD!":GOTO1080
5050 PRINT"[196]AHIN KANN ICH NICHT RUDERN!":GOTO1500
6000 IFSP<>3THENPRINT"[196]AS GEHT NICHT!":GOTO1500
6010 IFO1<>10THENPRINT"[215]IE BITTE?":GOTO1500
6020 SP=4:PRINT"[207].[203].":PO=PO+1:GOTO1080
6100 PRINT"[204]EIDER UNMOEGLICH!":GOTO1500
6500 IFO1=0THENPRINT"[215]AS DENN?":GOTO1500
6510 IFNOTO(O1)THENPRINT"[200]AB ISCH NISCH!":GOTO1500
6520 PRINT"[201]CH BIN DOCH NICHT SO BLOED UND VER-"
6530 PRINT"LIER WAS!"
6540 PRINT"[211]CHON AUS [208]RINZIP NICHT!":GOTO1500
7000 IFO2<>28ANDO2<>0THENPRINT"[215]HAT,TO THE [196]ONNERWETTER?":GOTO1500
7005 IFNOTO(O1)THENPRINT"[200]AB ICH NICHT!":GOTO1500
7010 IFO1<>23THENPRINT"[214]OELLIG UNLESERLICH!":GOTO1500
7020 PRINT"[207]HH NEIN,EIN [215]ERBE-[218]ETTEL..."
7030 PRINT"[211]OLL ICH IHN WIRKLICH LESEN?":GOSUB50000:POKE646,F2
7040 IFLEFT$(X$,1)="N"THENPRINT"[199]UT SO!":GOTO1500
7041 IFLEFT$(X$,1)<>"J"THEN7030
7050 PRINT"[196]ORT STEHT:"
7080 PRINTCHR$(34);:POKE646,F1
7090 PRINT"[208]INK [211]CHWERTPUTZER FUER IHR [211]CHWERT,"
7100 PRINT" JETZT IM [211]ONDERANGEBOT BY [193]RTHURS "
7110 PRINT" [210]ITTER- UND [203]NAPPENSHOP!"
7111 PRINT" [206]UR 19,50.-";
7119 POKE646,F2
7120 PRINTCHR$(34):GOTO1500
7500 IFO1=9THENPRINT"[215]AS BIST DU DENN FUER EINER?":GOTO1500
7510 IFO(O1)<>SPTHENPRINT"[211]EHE ICH HIER NICHT!":GOTO1500
7520 IFO1<12ORO1>16THENPRINT"[211]O EIN SCHWACHSINN!":GOTO1500
7530 IFO1=15THEN7700
7535 IFO1=14THEN7900
7540 IFFL(5)=0THEN7800
7550 PRINT"[199]UT,"NO$(O1)" IST NUN MEINE":PRINT"[198]RAU,";:PO=PO+1
7555 PRINT"UND IHR LIEBT EUCH UND WERDET"
7556 PRINT"GLUECKLICH SEIN BIS AN EUER [204]EBENSENDE!"
7557 PRINT"[207]DER?":PRINT
7560 POKE646,F1
7570 PRINT"[194]RAVO,DU HASST MICH GESCHLAGEN,DAS"
7580 PRINT"[193]DVENTURE IST GELOEST!"
7585 PRINT"[196]U ERHAELST"PO"VON 9 [208]UNKTEN!"
7590 PRINT"[193]BER FREU DICH NICHT ZU FRUEH,"
7595 PRINT"[212]EIL 2 IST SCHON IN [193]RBEIT!":PRINT:GOTO54000
7700 PRINT"[206]ILS,DER ANDERE [218]AUBERLEHRLING UND"
7710 PRINT"[205]EIKES [198]REUND,KOMM HEREIN UND ER-"
7720 PRINT"SCHLAEGT MICH AUS [197]IFERSUCHT!":PRINT:GOTO54000
7800 PRINT"[210]EIZVOLLER [199]EDANKE...[193]BER DAS [193]BENTEUER"
7810 PRINT"RUFT.[193]LSO BESTEHE ES UND SCHAFF DIR"
7820 PRINT"KEIN NEUES!":GOTO1500
7900 PRINT"[211]IE REISST MIR DIE [203]LEIDER VOM [204]EIBE."
7910 PRINT"[201]CH STERBE AN MEINER [197]RREGUNG!":PRINT:GOTO54000
8000 IFO2<>0THENPRINT"[206]ICHT ALLES AUF EINMAL!":GOTO1500
8001 IFO(O1)<>SPANDNOTO(O1)THENPRINT"[211]EH ICH NICHT,HAB ICH NICHT!":GOTO1500
8002 ONO1GOTO8010,8010,8010,8010,8010,8010,8020,8015,8300,8300,8050,8060,8070
8003 ONO1-13GOTO8080,8090,8100,8110,8300,8300,8300,8300,8120,8130,8140
8004 ONO1-24GOTO8150,8160,8300,8300,8140,8300,8180,8170
8010 PRINT"[213]NTERSUCH IHN DOCH SELBST!":GOTO1500
8015 PRINT"[203]ANNST DU NICHT AUF [196]EUTSCH REDEN!":GOTO1500
8020 PRINT"[201]CH BIN EIN SCHOENER,MUSKULOESER"
8021 PRINT"[202]UENGLING.[205]EIN [206]AME IST [206]EVS [197]NRA.":GOTO1500
8050 PRINT"[201]ST NICHT ZU SEHEN!":GOTO1500
8060 PRINT"[215]IE ICH SCHON SAGTE:[204]IEBLICH!":GOTO1500
8070 PRINT"[211]IE IST WIRKLICH SEHR,SEHR NIEDLICH!":GOTO1500
8080 PRINT"[205]AN,HAT DIE EIN [212]EMPERAMENT!":GOTO1500
8090 PRINT"[211]IE BLEIBT COOL,UND SO SIEHT SIE AUCH":PRINT"AUS!":GOTO1500
8100 PRINT"[197]IN NETTES [205]AEDEL":GOTO1500
8110 PRINT"[196]IE [200]UETTE IST KLEIN UND SCHEINT"
8111 PRINT"GEMUETLICH ZU SEIN.":GOTO1500
8120 PRINT"[197]S IST VERGOLDET UND MIT [197]DELSTEINEN":PRINT"BESETZT.":GOTO1500
8130 PRINT"[201]CH SOLTE ES LESEN!":GOTO1500
8140 PRINT"[197]S IST EIN EHER FREUNDLICHER [218]WERG!":GOTO1500
8150 PRINT"[196]AS IST ER...":GOTO1500
8160 PRINT"[196]U INHALIERST ZUVIEL [206]EBEL...[197]S IST":PRINT"[199]IFTGAS...[196]U [211]TIRBST!":PRINT
8161 GOTO54000
8170 PRINT"[211]IE KOENNTE NOCH NUETZLICH SEIN!":GOTO1500
8180 PRINT"[218]AUBERHAFT!":GOTO1500
8300 PRINT"[211]IEHT GANZ NORMAL AUS!":GOTO1500
30000 ONV2GOTO31000,31500,32000,32500,32500,33000,33500,34000,33500,34000,34500
30050 ONV2-11GOTO35000,35010,35020,35030,35040,35050,35500,35500,36000,37000
30060 ONV2-21GOTO33500,34000,38000,38000,39500,39700,40000
30100 GOTO1500
31000 PRINT"[201]CH TRAGE:"
31005 FL(3)=-1:FORT=7TOAO
31010 IFO(T)=-1THENFL(3)=0:PRINTNO$(T)"."
31020 NEXT
31030 IFFL(3)THENPRINT"GAR NICHTS!"
31040 GOTO1500
31500 IFSP=10THENPRINT"[196]IE [205]AEDELS SEHN ZUM ANBEISSEN AUS!":GOTO1500
31510 IFSP=17THENPRINT"[201]CH BIN MUEDE!":GOTO1500
31520 IFSP=5THENPRINT"[199]EH HIER NICHT WEITER!":GOTO1500
31530 IFSP=14ORSP=15THENPRINT"[205]AN SIEHT DEN [215]ALD VOR [194]AEUMEN NICHT!":GOTO1500
31540 IFSP=3THENPRINT"[201]CH WOLLT ICH WAER EIN [211]EEBAER,AEH      -MANN...":GOTO1500
31550 IFSP=31THENPRINT"[218]WERGE LIEBEN [204]ICHT!":GOTO1500
31555 IFSP=7THENPRINT"[201]CH SOLLTE DAS [194]OOT BESSER VERLASSEN!":GOTO1500
31560 IFSP=12THENPRINT"[199]IB AUF,HIER KOMMST DU NICHT MEHR WEG!":GOTO1500
31900 PRINT"[200]ILF DIR SELBST,":ZU=ZU-1
31910 PRINT"DANN HILFT DIR [199]OTT!"
31920 GOTO1500
32000 PRINT"[215]ILLST DU WIRKLICH AUFHOEREN?"
32010 GOSUB50000:POKE646,F2
32020 IFLEFT$(X$,1)="J"THENPRINT"[206]A GUT!":GOTO54000
32030 PRINT"[215]ARUM TIPPST DU DANN '[197]NDE'?":GOTO1500
32500 GOTO1080
33000 ZU=ZU-1:PRINT"[206]ICHT ZU DANKEN!":GOTO1500
33500 GOSUB56500:PRINT"[208]LEASE WAIT!":ZU=ZU-1
33510 OPEN15,8,15,"S:"+N$
33520 CLOSE15
33530 OPEN2,8,2,N$+",S,W"
33540 PRINT#2,SP:PRINT#2,ZU:PRINT#2,RA$(32):PRINT#2,NO$(25):PRINT#2,PO
33550 FORT=1TOAO:PRINT#2,O(T):NEXT
33560 FORT=1TOAF:PRINT#2,FL(T):NEXT
33600 CLOSE2:PRINT"[198]ERTIG."
33700 GOTO1500
34000 GOSUB56500:PRINT"[208]LEASE WAIT"
34030 OPEN2,8,2,N$+",S,R"
34040 INPUT#2,SP:INPUT#2,ZU:INPUT#2,RA$(32):INPUT#2,NO$(25):INPUT#2,PO
34050 FORT=1TOAO:INPUT#2,O(T):NEXT
34060 FORT=1TOAF:INPUT#2,FL(T):NEXT
34100 CLOSE2:PRINT"[198]ERTIG."
34200 GOTO1080
34500 PRINT"[194]ILDSCHIRMFARBE        ([198]1+[210]ETURN)  < >":POKE650,128
34510 GETA$:IFA$="[133]"THENF0=F0+1:IFF0=15THENF0=0
34520 IFA$=CHR$(13)THEN34540
34530 POKE53280,F0:POKE53281,F0:GOTO34510
34540 PRINT"[211]CHRIFTFARBE [197]INGABE   ([198]1+[210]ETURN)  > [146]<[157][157]";
34545 GETA$
34550 IFA$="[133]"THENF1=F1+1:IFF1=15THENF1=0
34560 IFA$=CHR$(13)THEN34580
34570 POKE646,F1:PRINT" [146][157]";:GOTO34545
34580 POKE646,F2:PRINT:PRINT"[211]CHRIFTFARBE AUSGABE   ([198]1+[210]ETURN)  > [146]<[157][157]";
34585 GETA$
34590 IFA$="[133]"THENF2=F2+1:IFF2=15THENF2=0
34595 IFA$=CHR$(13)THEN34600
34598 POKE646,F2:PRINT" [146][157]";:GOTO34585
34600 PRINT:PRINT"[211]CHRIFTFARBE [203]OPFZEILE ([198]1+[210]ETURN)  > [146]<[157][157]";
34610 GETA$
34620 IFA$="[133]"THENF3=F3+1:IFF3=15THENF3=0
34630 IFA$=CHR$(13)THEN34650
34640 POKE646,F3:PRINT" [146][157]";:GOTO34610
34650 POKE650,0:PRINT:GOTO1080
35000 X$="N":GOTO1520
35010 X$="S":GOTO1520
35020 X$="W":GOTO1520
35030 X$="O":GOTO1520
35040 X$="OB":GOTO1520
35050 X$="U":GOTO1520
35500 PRINT"[196]U HASST";:ZU=ZU-1
35510 IFZU=1THENPRINT" EINEN [194]EFEHL GEGEBEN!":GOTO35525
35511 IFZU=0THENPRINT" NOCH KEINEN [194]EFEHL GEGEBEN!":GOTO1500
35520 PRINTZU"[194]EFEHLE GEGEBEN!"
35525 IFPO=1THENPRINT"[196]U HASST EINEN [208]UNKT.":GOTO35560
35527 PRINT"[196]U HASST"PO"[208]UNKTE."
35560 PRINT"[193]BER DAS [211]PIEL HASST DU NOCH NICHT "
35570 PRINT"GEWONNEN!":GOTO1500
36000 X$=RIGHT$(X$,LEN(X$)-5)
36010 IFLEFT$(X$,1)<>CHR$(34)THENPRINT"[193]NFUEHRUNGSZEICHEN VERGESSEN!":GOTO1500
36011 IFRIGHT$(X$,1)<>CHR$(34)THENPRINT"[215]RONG [201]NPUT!":GOTO1500
36020 FORZA=1TOAZ
36030 IFZA$(ZA)=X$THEN36310
36040 NEXT
36300 PRINTX$",NICHTS PASSIERT!":GOTO1500
36310 ONZAGOTO36500,36600,36700,36800
36500 IFSP<>41THENPRINT"[200]IER GIBT'S NICHTS ZUM SCHWIMMEN!":GOTO1500
36505 IFFL(9)THENSP=18:FL(7)=0:PRINT"[208]UH,BIN DOCH GERETTET!":GOTO1080
36510 SP=18:FL(7)=0:FL(9)=-1:PRINT"[208]UH,BIN DOCH GERETTET!":PO=PO+1:GOTO1080
36600 IFSP<>33THENPRINT"[196]AS GEHT LEIDER NICHT!":GOTO1500
36610 IFFL(5)=0THENPRINT"[201]CH HABE DAS [211]CHWERT NOCH NICHT!":GOTO1500
36620 SP=2:PRINT"[218]WOOOCHH...[215]AU,ECHT GEIL SO'N [218]AUBER!":PO=PO+1:GOTO1080
36700 IFSP<>33THENPRINT"[201]CH SEH DEN [196]RACHEN JA GAR NICHT!":GOTO1500
36710 IFFL(6)THENPRINT"[196]ER [196]RACHE IST SCHON TOT!":GOTO1500
36720 PRINT:PRINT:PRINT:PRINT"[208]ENG,[218]ACK,[194]UFF..."
36730 PRINT"[194]LITZE ZUCKEN,[198]LAMMEN LODERN,DER [196]RACHE"
36731 PRINT"IST TOT,ENDLICH BESIEGT!"
36732 NO$(25)="DEN TOTEN [196]RACHEN":FL(6)=-1
36740 PRINT"[196]ER HEILIGE [205]ANN ERSCHEINT.[197]R SAGT:"
36750 PRINTCHR$(34);:POKE646,F1
36760 PRINT"[196]U HASST MEINE [197]RWARTUNGEN VOLL"
36761 PRINT" ERFUELLT.[201]CH LEGE NUN MEIN [193]MT NIEDER"
36762 PRINT" UND GEBE ALLES AN DICH,MEIN [211]CHUELER."
36763 PRINT" [204]EB WOHL...";:POKE646,F2:PRINTCHR$(34)
36770 PRINT"[201]CH RUFE IHM NOCH NACH,DOCH ER IST"
36771 PRINT"SCHON WEG.[206]UN BIN ICH DER [218]AUBERER UND"
36772 PRINT"HEILIGE [205]ANN."
36773 PRINT"[193]N DER [215]AND ERSCHEINT EINE [211]CHRIFT,DIE"
36774 PRINT"BESAGT,DASS DAS [193]DVENTURE NOCH NICHT":PRINT"GESCHLAGEN IST!"
36776 PO=PO+1
36777 PRINT"([205]ORE)[145][145]"
36780 GETA$:IFA$=""THEN36780
36785 FL(6)=-1:GOTO1080
36800 IFNOTO(32)THENPRINT"[200]AB' KEINE [204]AMPE!":GOTO1500
36810 IFSP<>32THENPRINT"[194]IN DOCH NICHT BLIND!":GOTO1500
36820 FL(4)=-1:PRINT
36830 PRINT"[196]ER [218]WERG FREUT SICH UEBER DAS [204]ICHT."
36840 PRINT"[201]CH SCHENKE IHM DIE [204]AMPE."
36845 PRINT"[197]R VERSTECKT SIE SCHNELL IN SEINER"
36850 PRINT"[200]OEHLE.":O(32)=0
36860 PRINT"[197]R BEGINNT ZU ERZAEHLEN:"
36861 PRINTCHR$(34);:POKE646,F1
36862 PRINT"[196]ER [196]RACHE IST MIT [205]AGIE EINFACH ZU"
36863 PRINT" BESIEGEN...BENUTZE DEIN [215]ISSEN!";
36864 POKE646,F2:PRINTCHR$(34)
36865 PRINT"[205]EHR WILL ER NICHT SAGEN!"
36866 PRINT"[197]R VERSCHWINDET...":O(24)=0
36870 RA$(32)="IN EINER HELLERLEUCHTETEN       [200]OEHLE.":PO=PO+1:GOTO1080
37000 IFSP<>17THENPRINT"[194]IN NICHT MUEDE!":GOTO1500
37010 PRINT"[204]ANGSAM SINKE ICH IN DEN [211]CHLAF...":SP=18
37020 FORT=1TO2000:NEXT
37030 PRINT"[201]CH ERWACHE,UND SEHE...[215][193][211]?"
37040 PRINT"[201]CH BIN JA GANZ WO ANDERS..."
37045 PO=PO+1:GOTO1080
38000 PRINT"[197]INE KOMPLETTE [193]NLEITUNG KANN ICH"
38010 PRINT"DIR SO AUF DIE SCHNELLE NICHT GEBEN,"
38020 PRINT"ABER EIN PAAR [212]RICKS:"
38030 PRINT"[211]AVE IMMER ALLES AB,BEVOR DU ETWAS GE-"
38040 PRINT"FAEHRLICHES AUSPROBIERST."
38050 PRINT"[213]NTERSUCHE ALLES GENAU UND LESE ALLES"
38060 PRINT"SORGFAELLTIG."
38070 PRINT"'SCORE' BZW. 'SPIELSTAND' SAGT DIR,WIE-"
38080 PRINT"VIELE [194]EFEHLE DU SCHON GEGEBEN HASST,"
38090 PRINT"UND DEINE [208]UNKTZAHL."
38095 PRINT"[218]AUBERSPRUECHE WERDEN ANGEWENDET,INDEM"
38100 PRINT"MAN 'SAGE "CHR$(34)"ZAUBERSPRUCH"CHR$(34)"' TIPPT."
38110 PRINT"[197]IN [218]AUBERSPRUCH IST EIN [194]EFEHL,DER"
38120 PRINT"RUECKWAERTS EINGEGEBEN WERDEN MUSS!":
38999 GOTO1500
39500 SYS867:PRINTCHR$(14)
39510 F0=0:F1=5:F2=3:F3=5
39530 GOTO39800
39700 PRINTCHR$(142):SYS820
39710 F0=6:F1=0:F2=15:F3=15
39800 :
39810 POKE53280,F0:POKE53281,F0
39830 GOTO1080
40000 PRINT"[196]IE [218]EIT VERGEHT...":GOTO1500
50000 X$="":A$="":POKE646,F1:PRINT:PRINT"[164][157]";
50030 GETA$:IFA$=""THEN50030
50031 POKE212,0
50033 IFA$=CHR$(13)THEN50300
50034 IFA$=""THENGOSUB50500:GOTO50030
50035 IFA$=CHR$(32)THEN50080
50036 IFA$=CHR$(34)THENPOKE212,1:GOTO50080
50037 IFA$=CHR$(20)THENGOSUB50400:GOTO50030
50038 IFLEN(X$)>78THEN50030
50050 IFA$<"A"ORA$>"Z"THEN50030
50080 PRINTA$;"[164][157]";:X$=X$+A$:GOTO50030
50300 IFLEN(X$)<1THENGOTO50030
50301 PRINT" ":RETURN
50400 L=LEN(X$):IFL<1THENRETURN
50415 X$=LEFT$(X$,L-1):PRINT" [157][157][164][157]";
50430 RETURN
50500 IFLEN(X$)<1THENRETURN
50501 PRINT" [157]";:FORS=1TOLEN(X$)
50510 PRINT" [157][157]";:NEXT
50520 PRINT"[164][157]";:X$="":RETURN
51000 FORI=1TO10:BE$(I)="":NEXT
51020 WZ=1
51030 FORI=1TOLEN(X$)
51040 IFMID$(X$,I,1)=" "THENGOSUB51100:GOTO51060
51045 IFWZ>10THENPRINT"[197]INGABE IST ZU LANG!":ER=1:RETURN
51050 BE$(WZ)=BE$(WZ)+MID$(X$,I,1)
51060 NEXT:GOSUB51100:WZ=WZ-1
51070 RETURN
51100 REM AUSSORTIEREN
51110 IC=0:FORI1=1TOAU
51120 IFBE$(WZ)=AU$(I1)THENIC=1
51130 NEXT
51140 IFIC=0THENWZ=WZ+1:RETURN
51150 BE$(WZ)="":RETURN
52000 IFBE$(1)="SAGE"THENV2=20:RETURN
52001 O2=0:V2=0:IFWZ>1THEN52008
52002 FORT=1TOA2:IFV2$(T)=BE$(1)THENV2=T:RETURN
52003 NEXT
52008 IFWZ>3THENPRINT"[215]AS SOLL DAS BEDEUTEN?":GOTO1500
52009 FORT=1TOAV
52010 IFVE$(T)=BE$(1)THENV=T:GOTO52100
52020 NEXT
52030 PRINT"'"BE$(1)"' KENNE ICH NICHT!":ER=1:RETURN
52100 FORT=1TOAO
52110 IFO$(T)=BE$(2)THENO1=T:GOTO52150
52120 NEXT
52130 PRINT"[203]EIN [206]OMEN GEFUNDEN!":ER=1:RETURN
52150 IFWZ=2THENRETURN
52200 FORT=1TOAO
52210 IFO$(T)=BE$(3)THENO2=T:GOTO52300
52220 NEXT
52230 PRINT"'"BE$(3)"' KENNE ICH NICHT!":ER=1
52300 RETURN
53000 X=PEEK(211):Y=PEEK(214):POKE646,F3
53010 PRINT"                               [212]HE [211]WORD[146]"
53020 PRINT"";KR$(SP);"[146]"
53030 POKE211,X:POKE214,Y:SYS58732
53050 RETURN
54000 POKE646,F2:PRINT"[206]OCHMAL?"
54010 GOSUB50000:IFLEFT$(X$,1)="J"THENPOKE53280,6:POKE53281,6:RUN20
54020 GOTO60000
56000 SYS867:RETURN
56500 PRINT"[198]ILE-[206]UMMER (1-3) [164][157]";
56510 GETE$:IFE$<>"1"ANDE$<>"2"ANDE$<>"3"THEN56510
56511 IFE$="1"THENN$="C"
56512 IFE$="2"THENN$="D"
56513 IFE$="3"THENN$="E"
56520 PRINTE$"_":RETURN
57000 POKE646,F2:PRINT
57010 PRINT"[196]ER HEILIGE [205]ANN ERBLICKT SEINEN"
57020 PRINT"[211]CHUELER (MICH) UND SAGT:"
57030 PRINTCHR$(34);:POKE646,F1
57040 PRINT"[201]CH BIN [211]TOLZ,MEIN [211]CHUELER!"
57050 PRINT" [196]U WOLLTEST [218]AUBERER WERDEN,UND JETZT"
57060 PRINT" STEHST DU VOR DER ABSCHLIESSENDEN"
57070 PRINT" [208]RUEFUNG.[212]OETE DEN [196]RACHEN,DER IN DEM"
57080 PRINT" [214]ULKAN '[214]ETUS' LEBT UND NIMM DAS"
57085 PRINT" [218]AUBERSCHWERT,DAS ER BEWACHT!"
57090 PRINT"[160][199]ELINGT DIR DIES,BIST DU WAHRLICH"
57091 PRINT" FUER WUERDIG BEFUNDEN,EIN [218]AUBERER"
57092 PRINT" ZU SEIN.";:POKE646,F2:PRINTCHR$(34)
57093 PRINT"[196]ER HEILIGE [205]ANN,MEIN [204]EHRMEISTER,"
57094 PRINT"SCHEINT SICH IN [204]UFT AUFZULOESEN!"
57095 PRINT"[202]ETZT BIN ICH AUF MICH GESTELLT!"
57100 PRINT"<[205]ORE>[145][145]"
57110 GETA$:IFA$=""THEN57110
57120 RETURN
60000 POKE59639,16:POKE53280,6:POKE53281,6
60010 SYS820
60020 PRINT"            [150]  [208]INK [193]RTS:"
60030 PRINT"        [144]\  [212] [200] [197]  [211] [215] [207] [210] [196]  \"
60031 PRINT"     @ 1986 BY [193].[211]OMMER AND [211].[193]DOMAT"
60035 PRINT"[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
60040 M$="        [212]HE [211]WORD BY [150][208]INK [193]RTS[144]":GOSUB61000
60050 M$="       [208]ROGRAMING : [193]RNE [211]OMMER":GOSUB61000
60060 M$="      [201]DEA : [193].[211]OMMER AND [211].[193]DOMAT":GOSUB61000
60065 M$="  [211]TORY AND [205]AP : [193].[211]OMMER + [211].[193]DOMAT":GOSUB61000
60070 M$="     [211]PECIAL [197]FFECTS : [211]VEN [193]DOMAT":GOSUB61000
60080 M$="     [199]RAFICS : [193].[211]OMMER + [211].[193]DOMAT":GOSUB61000
60090 M$="     [205]OTIVATION : [194]IRTHE [206]IETMANN":GOSUB61000
60100 M$="     [199]REETINGS TO ALL OUR FRIENDS!":GOSUB61000
60110 M$="[193]ND COMING SOON : [210]ITTER + [211]WORD [208]ART 2[157]":GOSUB61000
60120 M$=" [193]EHNLICHKEITEN MIT WIRKLICHEN [194]EGEBEN-  HEITEN UND [206]AMEN SIND REIN"
60130 M$=M$+" ZUFAELLIG!":GOSUB61000
60900 GOTO60040
61000 POKE214,24:POKE211,0:SYS58732
61010 PRINTM$:PRINT:PRINT:GOSUB62000
61020 PRINT:GOSUB62000:PRINT:GOSUB62000:PRINT:GOSUB62000:PRINT:GOTO62000
61030 RETURN
62000 FORT=1TO600:NEXT:RETURN